Estratégia Direcionada por Bandas de Bollinger

Definição

"Estratégia Direcionada" define os tipos de ordens que a estratégia pode criar. Se o valor da configuração for 0, ela pode ser tanto longa quanto curta. Se a definição for -1, ela só pode ser vendida e, se for 1, só pode ser comprada. A Estratégia de Direção das Bandas de Bollinger entra em posição de compra quando o símbolo cruza abaixo da banda inferior das bandas de Bollinger e entra em posição de venda se o símbolo cruza acima da banda superior. Mas lembre-se de que, nas configurações da estratégia, você pode ajustar a direção para ser somente longa, somente curta ou ambas.

Cálculos

Pine Script

//@version=5
strategy("Bollinger Bands Strategy directed", overlay=true)
source = close
length = input.int(20, minval=1)
mult = input.float(2.0, minval=0.001, maxval=50)
direction = input.int(0, title = "Strategy Direction", minval=-1, maxval=1)
strategy.risk.allow_entry_in(direction == 0 ? strategy.direction.all : (direction < 0 ? strategy.direction.short : strategy.direction.long))
basis = ta.sma(source, length)
dev = mult * ta.stdev(source, length)
upper = basis + dev
lower = basis - dev
if (ta.crossover(source, lower))
	strategy.entry("BBandLE", strategy.long, stop=lower, oca_name="BollingerBands", oca_type=strategy.oca.cancel, comment="BBandLE")
else
	strategy.cancel(id="BBandLE")
if (ta.crossunder(source, upper))
	strategy.entry("BBandSE", strategy.short, stop=upper, oca_name="BollingerBands", oca_type=strategy.oca.cancel, comment="BBandSE")
else
	strategy.cancel(id="BBandSE")
//plot(strategy.equity, title="equity", color=color.red, linewidth=2, style=plot.style_areabr)

Resumo

A Estratégia Direcionada por Bandas de Bollinger foi criada para comprar ou vender quando um símbolo estiver potencialmente acima de seu preço médio. Por exemplo, a estratégia pode ser direcionada para comprar se um símbolo está abaixo da Banda de Bollinger inferior ou vender se estiver acima da Banda de Bollinger superior. Alguns traders podem considerar isso como reversão à média porque as Bandas de Bollinger são criadas usando um desvio padrão do preço médio de um símbolo. Lembre-se de que a estratégia é direcionada e, nas configurações, você pode controlar o valor, ou seja, se for 0, ela será tanto comprada quanto vendida. Se a configuração for -1, ela só poderá operar vendido e, se for 1, só poderá operar comprado.