Estratégia da Avareza
Definição
A Estratégia da Avareza cria uma ordem inicial se houver um gap entre a abertura atual e a máxima ou mínima da barra anterior. Se a abertura for maior do que a máxima anterior, a estratégia será comprada; se a abertura for menor do que a mínima da barra anterior, ela abrirá uma posição vendida. Depois que uma posição é aberta, ela continuará a preencher ordens na mesma direção, desde que a cor da vela seja consistente com a posição aberta. Se a posição atual for comprada, novas ordens compradas serão criadas para cada candle verde subsequente e vice-versa. Isso continuará até que o candle de uma cor diferente ou até que o limite de ordens preenchidas para um dia seja atingido.
O limite pode ser alterado nas configurações, editando o valor Máximo de Rrdens Preenchidas Intradiárias. As configurações Tp e Sl permitem que você defina o Stop Loss e o Take Profit. O valor representa o número de minticks acima/abaixo do preço da posição em que o TP e o SL estarão localizados.
Cálculos
Pine Script
//@version=5
strategy("Greedy Strategy", pyramiding = 100, calc_on_order_fills=false, overlay=true)
tp = input(10)
sl = input(10)
maxidf = input(title="Max Intraday Filled Orders", defval=5)
strategy.risk.max_intraday_filled_orders(maxidf)
upGap = open > high[1]
dnGap = open < low[1]
dn = strategy.position_size < 0 and open > close
up = strategy.position_size > 0 and open < close
strategy.entry("GapUp", strategy.long, stop = high[1], when = upGap)
strategy.entry("Dn", strategy.short, stop = close, when = dn)
strategy.entry("GapDn", strategy.short, stop = low[1], when = dnGap)
strategy.entry("Up", strategy.long, stop = close, when = up)
strategy.cancel("GapUp", not upGap)
strategy.cancel("GapDn", not dnGap)
strategy.cancel("Up", not up)
strategy.cancel("Dn", not dn)
XQty = strategy.position_size < 0 ? -strategy.position_size : strategy.position_size
dir = strategy.position_size < 0 ? -1 : 1
lmP = strategy.position_avg_price + dir*tp*syminfo.mintick
slP = strategy.position_avg_price - dir*sl*syminfo.mintick
float nav = na
revCond = strategy.position_size > 0 ? dnGap : (strategy.position_size < 0 ? upGap : false),
strategy.order("TP", strategy.position_size < 0 ? strategy.long : strategy.short, XQty, lmP, nav, "TPSL", strategy.oca.reduce, "TPSL", when= not revCond and XQty > 0)
strategy.order("SL", strategy.position_size < 0 ? strategy.long : strategy.short, XQty, nav, slP, "TPSL", strategy.oca.reduce, "TPSL", when= not revCond and XQty > 0)
strategy.cancel("TP", XQty == 0 or revCond)
strategy.cancel("SL", XQty == 0 or revCond)
//plot(strategy.equity, title="equity", color=color.red, linewidth=2, style=plot.style_areabr)
Resumo
A Estratégia da Avareza foi criada para tirar proveito de gaps em qualquer direção. Em seguida, ela acelera para esses gaps, jogando o momentum para cima ou para baixo. A estratégia abre uma ordem inicial se houver um gap entre a abertura atual e a máxima ou mínima da barra anterior. Se a abertura for maior do que a máxima anterior, a estratégia entra em uma posição comprada e, se a abertura estiver abaixo da mínima da barra anterior, ela abre uma posição vendida. Depois que uma posição for aberta, ela continuará a preencher ordens na mesma direção, desde que a cor da vela seja consistente com a posição aberta.